Динамическая структура: линейный односвязный список с заглавным звеном

Главное меню статьи

Что такое "Список" и что такое "Список с заглавным звеном"?
Указатель на начало списка
Вспомогательные инструменты для проведения операций над списком
Добавление элемента в начало списка
Добавление элемента в конец списка
Добавление элемента перед заданным элементом списка
Добавление элемента после заданного элемента списка
Удаление первого элемента из списка
Удаление последнего элемента из списка
Печать элементов списка на экран из начала в конец
Реализация списка с заглавным звеном на языке программирования Turbo Pascal (ПРОГРАММА)

Для лучшего понимания данного материала ознакомьтесь с кратким очерком о классификации динамических структур данных.

Линейный односвязный список с заглавным звеном

Что такое "Список" и что такое "Список с заглавным звеном"?

Что же такое "Список" и его разновидность "Линейный односвязный список с заглавным звеном"?

Список - данные динамической структуры, представляющие собою совокупность линейно связанных однотипных элементов, для которого определены следующие фундаментальные операции:

  1. Добавление элемента в любое место списка.

  2. Удаление элемента из любой позиции списка.

Линейный односвязный список с заглавным звеном - тот же самый линейный односвязный список (ЛОС), но в дополнении имеющий специальный элемент, называемый заглавное звено, которое никогда не исключается из списка и служит для хранения вспомогательной информации о самом списке, например, о количестве элементов списка. Зачастую, заглавный элемент совсем не используются в программе и выполняют чисто формальную роль. Фундаментальные операции допустимые над списком с заглавным звеном совпадают с фундаментальными операциями над простым ЛОС.

Также, еще существует обязательная вспомогательная операция - печать элементов списка на экран, а если быть более точным, то происходит визуализация значений информационных полей элементов списка, так как в любом случае потребуется печать списка на экран пользователя, чтобы просмотреть, насколько корректно реализованы операции добавления и удаления элементов.

В целом, допустимы любые операции над линейным односвязным списком с заглавным звеном, после реализации которых, список остается в согласованном состоянии. К этим операциям можно отнести сортировку, слияние двух списков, расщепление списка на несколько списочных структур, получение количества элементов в списке, преобразование ЛОС в кольцевой список.

Фундаментальные операции допустимые над списком с заглавным звеном совпадают с фундаментальными операциями над простым ЛОС.

Указатель на начало линейного односвязного списка

head - указатель на заглавный элемент списка

Для корректной обработки линейного односвязного списка вводят понятие - указатель на начало списка. Как правило, именуется в программе подобный указатель словом head (в переводе с английского означает - голова). Данный указатель обязан указывать или ссылаться только на заглавный элемент списка, иначе список будет находиться в несогласованном состоянии. Надо понимать, что структурно заглавный элемент ничем не отличается от простого элемента списка и исполняет роль лишь служебного элемента, но заглавный элемент является обязательной частью линейного односвязного списка с заглавным звеном.

Информационное поле заглавного элемента очень часто выступает в роли хранителя общего количества элементов в текущем списке. Это облегчает проведения некоторых операций над списком, особенно когда требуется знать общее количество элементов. Иногда, заглавный элемент выступает в роли "мебели", то есть не выполняет никакой функциональности, кроме как ссылки на действительный первый элемент списка.

Вспомогательные инструменты для проведения операций над списком

Абсолютно во всех операциях, производимых над списком, требуется вспомогательный указатель, помимо указателя head, ссылающегося на заглавный элемент односвязного линейного списка. Во всех программах и фрагментах программного кода, представленных ниже, будем обозначать вспомогательный указатель идентификатором p (почему "p"? потому что с английского слово pointer переводится на русский как указатель).

Если требуется несколько вспомогательных указателей, то будем именовать их по принципу p1, p2, p3 и т. д.

Что же такое "NIL"?

NIL - специальный зарезервированный участок памяти, служащий "бухтой" для динамических переменных-указателей. Чтобы указатели "не болтались" в памяти, их обычно "привязывают" к NIL.

Добавление элемента в начало линейного односвязного списка

Линейный односвязный список обладает широкими возможностями вставки новых элементов, а именно:

  • добавление элемента в начало списка;

  • добавление элемента в конец списка;

  • добавление элемента перед заданным элементом;

  • добавление элемента после заданного элемента.

По сути, вставку можно произвести абсолютно в любую позицию существующего списка. Рассмотрим более детально вставку нового элемента в начало списка. Допустим, список является пустым, то есть заглавный элемент указывает в NIL.

Из данного изображения следует то, что линейный односвязный список является пустым, то есть не содержит ни одного элемента.

В процессе операции добавления требуется списочный элемент. Во всех операциях вставки будем его идентифицировать как add. То есть add - указатель на добавляемый элемент. В данном случае, add указывает на элемент, который станет первым добавленным элементом в линейный список с заглавным звеном.

И указатель head, и указатель add имеют одинаковую "анатомию", но в программе у них различная логическая роль. Как правило, в программах по формированию линеного односвязного списка, имеется функция, отвечающая за выделение памяти под добавляемый элемент.

 

Как видно из схемы, представленной слева, для того, чтобы провести операцию вставки элемента в начало списка достаточно линковочное поле заглавного элемента установить на добавляемый элемент.

То есть происходит перемещение указателя, который ссылался в NIL, на добавляемый элемент, то есть на тот участок памяти, куда ссылается указатель add.

По сути, односложная операция, требующая минимальное количество знаний от программиста.

Также, как видно из картинки, представленной слева, информационное поле заглавного звена принимает значение равное 1, т к был добавлен первый элемент в линейный односвязный список.

 

Рассмотрим вставку нового элемента в начало линейного односвязного списка с заглавным звеном, содержащего определенное количество элементов.

В приведенном примере, список содержит три элемента. Напомню, что информационное поле заглавного звена отвечает за текущее количество элементов в списке.

Как мы ранее и договаривались, указатель, ссылающийся на добавляемый элемент будет называться add, а линковочное поле добавляемого элемента находится в согласованном состоянии, так как "смотрит" в NIL.

Чтобы корректно произвести операцию вставки, в первую очередь нужно связать линковочное поле добавляемого элемента с первым элементом данного списка.

Для этого указатель, который ссылался в NIL устанавливаем на тот участок памяти, на который ссылается линковочное поле заглавного элемента однонаправленного списка.

Таким образом уже образуется кое-какая взаимосвязь между добавляемым элементом и первым элементом списка.

Поскольку на первый элемент ссылается линковочное поле добавляемого элемента, то можно перевести линковочное поле заглавного звена на добавляемый элемент, причем, нарушение или разрыва линейного односвязного списка не произойдет.

Другими словами, линковочное поле заглавного звена стало указывать на новоиспеченный элемент, именуемый add.

Список находится в согласованном состоянии.

В итоге увеличиваем общее количество элементов данного списка на один и производим визуализацию конечного состояние списка.

Линейный односвязный список с заглавным звеном пребывает в согласованном состоянии, так как линковочное поле заглавного элемента ссылается на "новый" первый элемент, а линковочное поле замыкающего элементы ссылается в NIL.

Добавление элемента в конец Списка

Операция добавления элемента в конец списочной структуры чуть более сложная, чем операция добавления элемента в начало списка.

Предположим, что в данном континууме существует список с заглавным звеном, состоящий из двух элементов. Кстати, информационное поле заглавного элемента хранит значение равное 2, что говорит нам о том, что в данный момент времени список состоит из двух реляционных элементов.

Список находится в согласованном состоянии. Также имеется указатель add, ссылающий на добавляемый элемент, который необходимо позиционировать в конец списка.

Для продолжения проведения операции добавления элемента в конец линейного односвязного списка с заглавным звеном, потребуется вспомогательный указатель р, который необходимо установить на заглавный элемент данного ЛОС.

Сейчас нашей целью является достижения данным указателем р самого крайнего с конца элемента списка. Для этого потребуется циклически смещаться по одному элементу.

На первой итерации происходит позиционирование указателя р на второй элемент списка.

Не трудно догадаться, что цикл будет выполняться до тех пор, пока линковочное поле, на которое ссылается идентификатор р не станет указывать в NIL. На второй итерации указатель р достигает последнего элемента.

Итак, вспомогательный указатель p достиг последнего элемента линейного односвязного списка.

Переставляем линковочное поле последнего элемента списка на добавляемый элемент. И в принципе на этом операция добавления элемента в конец линейного односвязного списка с заглавным элементом считается проведенной.

Список находится в согласованном состоянии, связь между элементами "не порвана", линковочное поле последнего элемента списка ссылается в NIL.

Увеличиваем количество элементов списка на единицу. Теперь текущее количество составляет три.

Список находится в абсолютно согласованном состоянии, так как указатель на заглавный элемент ссылается на заглавное звено, а последний элемент списка указывает в NIL.

Вывод: операция добавления элемента в конец линейного односвязного списка с заглавным звеном успешно проведена.

Добавление элемента перед заданным элементом

Допустим, существует линейный односвязный список с заглавным звеном, состоящий из 5 элементов.

Указатель head ссылается на элемент, называемый заглавное звено.

Линковочное поле заглавного элемента ссылается на первый элемент данного односвязного списка.

Список находится в согласованном состоянии.

add - название указательной переменной, которая ссылается на добавляемый элемент

Итак, наша задача - вставить новый элемент перед заданным элементом данного линейного односвязного списка. Каемка заданного элемента помечена красным цветом.

Потребуется вспомогательный указатель р, ссылающийся на заглавное звено всего списка.

В качестве примера выбран список, состоящий из 5 элементов.

Необходимо поставить вспомогательный указатель р на элемент, стоящий перед "красным" элементом, то есть, требуется циклический пробег по списку.

На первой итерации смещаем указатель р на первый элемент списка.

Напомню, что заглавный элемент и первый элемент списка - различные узлы.

На второй итерации указатель р достигает нужно положения, то есть, оказывается на элементе, стоящем перед элементом, помеченным красным цветом.

Как видно из рисунка, "красный" элемент имеет номер 3, а указатель p достиг уже элемента под номером 2.

Производим перевод линковочного поля добавляемого элемента на элемент, перед которым необходимо произвести добавление, то есть, уводим ссылку с NIL на "красный" элемент.

То есть связь добавляемого элемента и элемента, перед которым нужно было произвести вставку - проведена.

Но это только первая операция.

Вторым действием обеспечиваем связь между добавляемым элементом и левым его "соседом".

Для этого перемещаем линковочное поле 2-го элемента на добавляемый элемент.

Вот теперь добавленный элемент четко позиционирован в нужное место с соблюдением всех необходимых взаимосвязей.

В итоге список находится в абсолютно согласованном состоянии, так как указатель head указывает на заглавное звено, а завершающий элемент списка ссылается в NIL.

Также количество элементов списка увеличиваем на единицу.

Вывод: операция добавления элемента в список с заглавным звеном перед заданным элементом успешно проведена.

Добавление элемента после заданного элемента

Покажем лишь непосредственно схемы добавления элемента. Граница заданного элемента помечена красным цветом. Также, для проведения данной операции требуется вспомогательный указатель р. Читать схему следует построчно слева направо.

Вывод: операция добавления элемента после заданного элемента списка с заглавным звеном успешно проведена

Удаление первого элемента из списка

Удаление элемента из линейного односвязного списка с заглавным звеном физически возможно, если список в своем составе содержит хотя бы один узел.

Рассмотрим удаление первого элемента из списка с заглавным звеном, состоящего из трех элементов.

Не нужно путать первый элемент и заглавный элемент, так как это не один и тот же узел списка.

Для проведения операции удаления потребуется вспомогательный указатель р.

Установим идентификатор р на первый или удаляемый узел линейного односвязного списка. Также отметим каемку удаляемого элемента красным цветом.

Наша задача - уничтожение "красного" элемента из данного списка, при этом сам список должен остаться в согласованном состоянии.

Поскольку на первый элемент списка ссылается указатель р, то связь между заглавным звеном и первым узлом можно разорвать не боясь повредить внутренние связи динамической структуры.

Для этого переставляем линковочное поле заглавного элемента на второй элемент списка.

Полностью "отвязываем" начальный элемент списка, для этого его связующее поле устанавливаем в NIL.

Данную операцию можно провести абсолютно безболезненно, так как на второй элемент списка ссылается линковочное поле заглавного элемента

По сути, мы "отделили" удаляемый элемент от списка, следовательно, можно переходит к этапу уничтожения отделенного элемента.

Проводим абсолютно безболезненно операцию удаления первого элемента из линейного односвязного списка с заглавным звеном.

В различных языках программирования, команда, отвечающая за уничтожение ранее распределенной памяти, называется по-разному. В языке программирования Pascal, для высвобождения памяти необходимо использовать процедуру Dispose, в языке программирования "чистый" С необходимо вызвать функцию free.

Уменьшаем количество элементов списка на единицу. Теперь список состоит из двух полноценных динамических элементов.

Также надо заметить тот факт, что список находится в согласованном состоянии, так как указатель head ссылается на заглавный элемент, который в свою очередь ссылается на первый элемент списка, а замыкающий элемент списка ссылается в NIL.

Вывод: операция удаления первого элемента из списка с заглавным звеном успешно проведена.

Удаление последнего элемента из списка

Принцип удаления последнего элемента из списка заключается в следующем: необходимо позиционироваться вспомогательным указателем на предпоследний элемент и, используя его, удалить завершающий узел из списка, с сохранением всех внутренних связей. Визуализируем схематично процесс удаления последнего элемента из списка. Читать данную схему нужно построчно слева направо.

В итоге список состоит из двух элементов, причем находится список в согласованном состоянии, так как указатель head ссылается на заглавное звено, а завершающий узел списка указывает в NIL. Также внутренние связи остались в консистентном положении, то есть, неразрушенными.

Вывод: операция удаления последнего элемента из линейного односвязного списка с заглавным звеном успешно проведена.

Примечание: удалить заглавное звено из списка невозможно - противоречит определению односвязного списка с заглавным звеном

Печать элементов списка на экран (из начала в конец)

Под печатью списка понимают визуализацию значений информационных полей каждого из элементов списка.

Следовательно, требуется последовательный просмотр всех узлов списка.

Справа представлена итеративная схема, демонстрирующая, каким образом производится перебор элементов заданного списка.

Для корректной реализации данной процедуры требуется вспомогательный указатель р, стартующий с первого узла списка.

Желтыми областями помечено значение информационного поля печатаемого на дисплей пользователя элемента.

Вывод: список после печати всех элементов остался в согласованном состоянии, следовательно, операция печати всех узлов списка с заглавным узлом из начала в конец успешно проведена.

Примечание: существует также операция печати элементов линейного списка из конца в начало и реализуется рекурсивным способом

Реализация списка с заглавным звеном на языке программирования Turbo Pascal 7.0

Предлагаю вашему вниманию программу на языке высокого уровня Turbo Pascal - реализация линейного односвязного списка с заглавным элементом без обработки исключительных ситуаций, используя глобальный указатель, ссылающийся на заглавный узел списка, то есть не используется парадигма передачи параметров между подпрограммами и главной программой. Список способен обрабатывать только строковые значения. Как я ранее писал в данной статье, выбор типа данных не является критичным и легко может быть заменен на нужный тип данных.

Программа реализует следующие операции над списком:

  • добавление элемента в начало списка;

  • добавление элемента  в конец списка;

  • добавление элемента перед заданным элементом;

  • добавление элемента после заданного элемента;

  • удаление элемента из начала списка;

  • удаление элемента из конца списка;

  • удаление срединного элемента;

  • печать элементов списка на дисплее пользователя (от начала к концу);

  • получение общего количества элементов в списке;

  • удаление всех элементов из списка.

Скачать программу реализации динамического списка с заглавным звеном на языке программирования Turbo Pascal 7.0.

Если вас интересует реализация дополнительного функционала по рассмотренной списочной структуре, например, вы хотите познакомиться с какой-либо функцией или процедурой, не представленной в этой статье, то сообщите об этом администратору сайта, связавшись с ним через форму обратной связи.

{заголовок программы}
program LIST_HEAD;
{раздел подключения модулей}
uses
{подключаем модуль crt - console run time, чтобы можно было использовать
 подпрограммы для работы с консолью}

    crt;
{раздел объявления пользовательских типов данных}
type
{указательный тип данных на элемент очереди}
    Tptr = ^Telem;
{запись, состоящая из двух полей, описывающая элемент очереди}
    Telem = record
{информационное поле элемента - хранит строковые значения}
        inf  : string;
{указательное поле на следующий элемент очереди}
        link : Tptr;
{конец описания записи}
    end;
{раздел декларации глобальных переменных}
var
{указатель на заглавный элемент линейного односвязного списка}
    head : Tptr;
{---------------------------------------------------------------------------}
{Функция: получение количества элементов списка. В качестве ответа функция
 возвращает количество элементов в списке}

{---------------------------------------------------------------------------}
function getCountElem : integer;
var
{переменная, хранящая количество элементов в списке. Причем данное значение
 хранится в информационном поле заглавного элемента списка, причем в
 строковом виде, то есть надо будет делать перевод из строки в число}

    number    : integer;
{хранит код ошибки, которая может возникнуть в процессе перевода из строки
 в числовое значение}

    errorCode : integer;
{начало тела функции}
begin
{вызываем процедуру перевода из строки в число}
    val(head^.inf, number, errorCode);
{в качестве ответа функция возвращает количество элементов в списке}
    getCountElem := number;
{конец тела функции}
end;
{---------------------------------------------------------------------------}
{Процедура: слежение за заглавным звеном.
 Логический параметр pb работает следующим образом: если передается ИСТИНА,
 то происходит увеличение количества элементов на 1, иначе уменьшение на 1}

{---------------------------------------------------------------------------}
procedure headElem(pb : boolean);
var
{переменная, хранящая количество элементов в списке. Причем данное значение
 хранится в информационном поле заглавного элемента списка, причем в
 строковом виде, то есть надо будет делать перевод из строки в число}

    number    : integer;
{хранит код ошибки, которая может возникнуть в процессе перевода из строки
 в числовое значение}

    errorCode : integer;
{начало тела процедуры}
begin
{вызываем процедуру перевода из строки в число}
    val(head^.inf, number, errorCode);
{происходит увеличение количества элементов}
    if(pb = TRUE) then
{на единицу}
        number := number + 1
{иначе текущее количество элементов уменьшается на единицу}
    else
        number := number - 1;
{используем процедуру для перевода значения из числа в строку, так как
 информационное поле заглавного элемента способно хранить только текстовые
 значения, а не числовые величины}

    str(number, head^.inf);
{конец тела процедуры}
end;
{---------------------------------------------------------------------------}
{Функция: создание элемента списка.
 В качестве ответа функция возвращает ссылку на сам объект / элемент}

{---------------------------------------------------------------------------}
function createElem : Tptr;
var
{указатель на только что созданный элемент в динамической памяти}
    add : Tptr;
{начало тела функции}
begin
{выделяем память под элемент}
    new(add);
{чтобы линковочное поле созданного элемента не "болталось" в памяти,
 привязываем его к NIL}

    add^.link := NIL;
{диалог пользователю о предстоящем вводе}
    write('Введите значение добавляемого элемента: ');
{считывание значения вводом с клавиатуры}
    readln(add^.inf);
{в качестве ответа функция возвращает ссылку на созданный элемент}
    createElem := add;
{конец тела функции}
end;
{---------------------------------------------------------------------------}
{Процедура: добавление элемента в начало списка с заглавным звеном}
{---------------------------------------------------------------------------}
procedure addElemToBegin;
var
{указатель на добавляемый элемент}
    add : Tptr;
{начало тела процедуры}
begin
{создание нового элемента}
    add := createElem;
{устанавливаем связь между только что созданным элементом и первым элементом
 списка (не стоит путать ПЕРВЫЙ элемент и ЗАГЛАВНЫЙ элемент списка!)}

    add^.link := head^.link;
{поскольку добавился новый элемент в начало списка, то заглавный элемент
 ссылается уже на второй, что неправильно, следовательно, связываем
 заглавный элемент и только что добавленный новый элемент в списке}

    head^.link := add;
{увеличиваем общее количество элементов в списке на единицу}
    headElem(TRUE);
{конец тела процедуры}
end;
{---------------------------------------------------------------------------}
{Процедура: добавление элемента в конец списка с заглавным звеном}
{---------------------------------------------------------------------------}
procedure addElemToEnd;
var
{указатель на добавляемый элемент}
    add : Tptr;
{вспомогательный указатель, требующийся для корректной работы}
    p   : Tptr;
{начало тела процедуры}
begin
{создание добавляемого элемента}
    add := createElem;
{позиционируем вспомогательный указатель на заглавный элемент}
    p := head;
{указатель р будет перемещаться по списку до тех пор, пока не выйдет
 на последний элемент списка}

    while(p^.link <> NIL) do
{циклически переходим на следующий элемент списка}
        p := p^.link;
{устанавливаем связь между последним и добавляемым элементом}
    p^.link := add;
{увеличиваем общее количество элементов в списке на единицу}
    headElem(TRUE);
{конец тела процедуры}
end;
{---------------------------------------------------------------------------}
{Процедура: добавление элемента перед заданным элементом}
{---------------------------------------------------------------------------}
procedure addElemBeforeTarget;
var
{добавляемый элемент в список}
    add       : Tptr;
{вспомогательный указатель для проведения операции добавления}
    p         : Tptr;
{хранит номер элемента перед которым будет производиться операция вставки}
    index     : integer;
{счетчик цикла}
    i         : integer;
{начало тела процедуры}
begin
{надо понимать следующее: если количество элементов в списке меньше двух, то
 невозможно добавить элемент перед заданным, это уже будет операция,
 равноценная операции добавления элемента в начало списка}

    if(getCountElem <= 1) then
{диалог пользователю о невозможности проведения операции добавления}
        writeln('Список содержит недостаточное количество элементов для вставки!')
{иначе}
    else
    begin
{выпечатываем пользователю подсказку об общем количестве элементов списка
 на данный момент}

        writeln('На данный момент в списке элементов: ', getCountElem);
{циклически запрашиваем номер элемента перед которым необходимо произвести
 вставку. Также проверяем, чтобы введенный индекс находился в допустимых
 диапазонах}

        repeat
            write('Введите номер элемента перед которым происходит вставка [2 ...', getCountElem, ']: ');
            readln(index);
        until((index >= 2) and (index <= getCountELem));
{устанавливаем вспомогательный указатель на первый элемент списка}
        p := head^.link;
{необходимо "допрыгать" указателем р до элемента, стоящего перед элементом,
 перед которым будет производится вставка нового элемента, поэтому в цикле
 правая граница счетчика составляет значение index - 2}

        for i := 1 to index - 2 do
{переход на следующий элемент списка}
            p := p^.link;
{выделяем память под добавляемый элемент}
        add := createElem;
{устанавливаем связь между новым элементом и элементом перед которым данный
 новый элемент будет вставлен}

        add^.link := p^.link;
{устанавливаем связь между новым элементом и элементом, стоящим перед элементом
 перед которым производится вставка}

        p^.link := add;
{общее количество элементов списка увеличиваем на единицу}
        headElem(TRUE);
{диалог пользователю об успешно проведенной операции}
        writeln('Элемент успешно добавлен перед заданным элементом!');
    end;
{конец тела процедуры}
end;
{---------------------------------------------------------------------------}
{Процедура: добавление элемента после заданного элемента}
{---------------------------------------------------------------------------}
procedure addElemAfterTarget;
var
{указатель на добавляемый элемент}
    add       : Tptr;
{вспомогательный указатель для проведения операции вставки}
    p         : Tptr;
{номер элемента после которого планируется добавить новый элемент}
    index     : integer;
{счетчик цикла}
    i         : integer;
{хранит общее количество элементов в списке. Дело в том, что существует уже
 специальная функция, определяющая общее количество элементов списка, но,
 чтобы не тратить ресурсы программы на постоянные вызовы, лучше задействовать
 специальную отдельную переменную}

    number    : integer;
{начало тела процедуры}
begin
{получаем общее количество элементов списка}
    number := getCountElem;
{надо понимать следующее: если количество элементов в списке меньше двух, то
 невозможно добавить элемент после заданного элемента, это уже будет операция,
 равноценная операции добавления элемента в конец списка}

    if(number <= 1) then
{диалог пользователю о том, что операцию добавления невозможно провести}
        writeln('Список содержит недостаточное количество элементов для вставки!')
{иначе}
    else
    begin
{сообщаем пользователю общее количество элементов в списке на текущий момент}
        writeln('На данный момент в списке элементов: ', number);
{циклически запрашиваем номер элемента перед которым необходимо произвести
 вставку. Также проверяем, чтобы введенный индекс находился в допустимых
 диапазонах}

        repeat
            write('Введите номер элемента после которого происходит вставка [1 ...', number - 1, ']: ');
            readln(index);
        until((index >= 1) and (index <= number - 1));
{устанавливаем указатель р на первый элемент списка (напомню, что первый
 элемент и заглавный элемент списка - разные элементы!)}

        p := head^.link;
{необходимо "допрыгать" указателем р до элемента, после которого необходимо
 произвести вставку нового элемента}

        for i := 1 to index - 1 do
{перемещаемся на следующий элемент списка}
            p := p^.link;
{выделяем память под добавляемый элемент}
        add := createElem;
{устанавливаем связь между добавляемым элементом и элементом, перед которым
 добавляемый элемент будет вставлен}

        add^.link := p^.link;
{устанавливаем связь между добавляемым элементом и элементом, после которого
 добавляемый элемент будет вставлен}

        p^.link := add;
{общее количество элементов списка увеличиваем на единицу}
        headElem(TRUE);
{диалог пользователю об успешном добавлении элемента}
        writeln('Элемент успешно добавлен после заданного элемента!');
    end;
{конец тела процедуры}
end;
{---------------------------------------------------------------------------}
{Процедура: удаление элемента из начала списка}
{---------------------------------------------------------------------------}
procedure delElemFromBegin;
var
{вспомогательный указатель, помогающий произвести операцию удаления}
    p      : Tptr;
{начало тела процедуры}
begin
{если в списке нет ни одного элемента, то удаление физически невозможно}
    if(getCountElem < 1) then
        writeln('В списке не обнаружено элементов! Удаление невозможно!')
{иначе в списке имеется хотя бы один элемент и удаление физически возможно}
    else
    begin
{устанавливаем вспомогательный указатель на первый элемент списка}
        p := head^.link;
{перемещаем заглавный элемент на второй элемент списка, то есть фактически
 убираем заглавный элемент с первого элемента}

        head^.link := p^.link;
{полностью "отвязываем" первый элемент, чтобы он ни на что больше не ссылался}
        p^.link := NIL;
{удаляем первый элемент из списка}
        dispose(p);
{оповещаем пользователя об успешном удалении элемента}
        writeln('Элемент успешно удален из начала списка!');
{уменьшаем количество элементов в списке на единицу}
        headElem(FALSe);
    end;
{конец тела процедуры}
end;
{---------------------------------------------------------------------------}
{Процедура: удаление элемента из конца списка}
{---------------------------------------------------------------------------}
procedure delElemFromEnd;
var
{вспомогательный указатель, помогающий произвести удаление элемента}
    p      : Tptr;
{начало тела процедуры}
begin
{если в списке нет ни одного элемента, то удаление физически невозможно}
    if(getCountElem < 1) then
        writeln('В списке не обнаружено элементов! Удаление невозможно!')
{иначе в списке имеется хотя бы один элемент и удаление физически возможно}
    else
    begin
{устанавливаем вспомогательный указатель на заглавный элемент списка!
 НАПОМНЮ, что заглавный и первый элемент списка - разные элементы}

        p := head;
{задача указателя р - достичь предпоследнего элемента списка, то есть
 встать перед удаляемым элементом}

        while(p^.link^.link <> NIL) do
{переход на следующий элемент}
            p := p^.link;
{производим удаление последнего элемента из списка}
        dispose(p^.link);
{и чтобы список остался в согласованном состоянии, надо, чтобы последний
 элемент (до удаления он являлся предпоследним) ссылался в NIL}

        p^.link := NIL;
{оповещение пользователя об успешном удалении элемента из списка}
        writeln('Элемент успешно удален из конца списка!');
{уменьшаем количество элементов на единицу}
        headElem(FALSe);
    end;
{конец тела процедуры}
end;
{---------------------------------------------------------------------------}
{Процедура: удаление срединного элемента}
{---------------------------------------------------------------------------}
procedure delCenterElem;
var
{вспомогательные указатели для удаления срединного элемента из списка}
    p, p1  : Tptr;
{отвечает за общее количество элементов в списке}
    number : integer;
{отвечает за номер удаляемого элемента}
    index  : integer;
{счетчик цикла}
    i      : integer;
{начало тела процедуры}
begin
{вычисляем общее количество элементов в списке}
    number := getCountElem;
{срединный элемент - это любой элемент в списке, не являющийся первым или
 последним элементом, поэтому, если в списке меньше трех элементов, то
 срединных элементов нет в списке и удалять нечего}

    if(number <= 2) then
        writeln('В списке нет срединных элементов!')
{иначе в списке больше двух элементов}
    else
    begin
{запрашиваем от пользователя номер удаляемого элемента, причем номер элемента
 не должен быть первым или последним}

        repeat
            write('Введите номер удаляемого элемента [2 ...', number - 1, ']: ');
            readln(index);
        until((index >= 2) and (index <= number - 1));
{устанавливаем вспомогательный указатель на первый элемент списка}
        p := head^.link;
{устанавливаем указатель р на элемент, стоящий перед удаляемым элементом}
        for i := 1 to index - 2 do
            p := p^.link;
{устанавливаем вспомогательный указатель р1 на удаляемый элемент}
        p1 := p^.link;
{разрываем связь между удаляемым элементом и элементом, стоящим перед
 удаляемым и связываем элементы перед удаляемым и после удаляемого}

        p^.link := p1^.link;
{разрываем связь между удаляемым элементом и элементом, стоящим после
 удаляемого элемента}

        p1^.link := NIL;
{производим операцию удаления элемента}
        dispose(p1);
{оповещаем пользователя об успешном удалении}
        writeln('Срединный элемент успешно удален из списка!');
{уменьшаем количество элементов списка на единицу}
        headElem(FALSE);
    end;
{конец тела процедуры}
end;
{---------------------------------------------------------------------------}
{Процедура: удаление всех элементов из списка}
{---------------------------------------------------------------------------}
procedure delAllElem;
var
{вспомогательный указатель, помогающий удалить все списочные элементы}
    p : Tptr;
{начало тела процедуры}
begin
{устанавливаем вспомогательный указатель р на первый элемент списка}
    p := head^.link;
{пока в списке не останется элементов, то есть когда заглавный элемент списка
 будет ссылаться в NIL, производим удаление элементов поштучно}

    while(head^.link <> NIL) do
    begin
{перемещаем заглавный элемент на второй элемент списка}
        head^.link := p^.link;
{разрушаем связь между первым и вторым элементом списка, поскольку сейчас
 первый элемент будет удален}

        p^.link := NIL;
{производим удаление первого элемента списка}
        dispose(p);
{вспомогательный указатель р устанавливаем на "новый" первый элемент списка}
        p := head^.link;
    end;
{конец тела процедуры}
end;
{---------------------------------------------------------------------------}
{Процедура: печать элементов списка из начала в конец}
{---------------------------------------------------------------------------}
procedure printListFromBeginToEnd;
var
{вспомогательный указатель, помогающий произвести операцию печати списка}
    p : Tptr;
{начало тела процедуры}
begin
{устанавливаем вспомогательный указатель на первый элемент списка, если
 таковой имеется, иначе указатель начинает ссылаться в NIL}

    p := head^.link;
{обращаемся к заглавному элементу и получаем количество элементов списка.
 Напомню, что информационное поле заглавного элемента хранит общее количество
 элементов во всем списке}

    writeln('Количество элементов в списке: ', head^.inf);
{если в списке нет ни одного элемента, то оповещаем об этом пользователя}
    if(head^.link = NIL) then
        writeln('Печать невозможна, так как список не содержит элементов!')
{иначе в списке имеется хотя бы один элемент}
    else
    begin
{начинаем пробежку по списку и выпечатываем информационные поля элементов на
 экран пользователю}

        write('Список имеет вид: ');
        while(p <> NIL) do
        begin
{печать значения элемента на экран пользователя}
            write(p^.inf, ' ');
{переход к следующему элементу списка}
            p := p^.link;
        end;
    end;
{конец тела процедуры}
end;
{---------------------------------------------------------------------------}
{Функция: главное меню программы}
{---------------------------------------------------------------------------}
function mainMenu : integer;
var
{отвечает за номер пункта выбранного пользователем}
    sel : integer;
{начало тела функции}
begin
{циклически пользователю предлагается выбрать один из пунктов для совершения
 соответствующей операции, причем, проверяется, чтобы его выбор был правилен}

    repeat
        clrscr;
        writeln(' 1 - ДОБАВЛЕНИЕ ЭЛЕМЕНТА В НАЧАЛО СПИСКА');
        writeln(' 2 - ДОБАВЛЕНИЕ ЭЛЕМЕНТА В КОНЕЦ СПИСКА');
        writeln(' 3 - ДОБАВЛЕНИЕ ЭЛЕМЕНТА ПЕРЕЗ ЗАДАННЫМ ЭЛЕМЕНТОМ');
        writeln(' 4 - ДОБАВЛЕНИЕ ЭЛЕМЕНТА ПОСЛЕ ЗАДАННОГО ЭЛЕМЕНТА');
        writeln(' 5 - УДАЛЕНИЕ ЭЛЕМЕНТА ИЗ НАЧАЛА СПИСКА');
        writeln(' 6 - УДАЛЕНИЕ ЭЛЕМЕНТА ИЗ КОНЦА СПИСКА');
        writeln(' 7 - УДАЛЕНИЕ СРЕДИННОГО ЭЛЕМЕНТА');
        writeln(' 8 - ПЕЧАТЬ ЭЛЕМЕНТОВ СПИСКА ИЗ НАЧАЛА В КОНЕЦ');
        writeln(' 9 - ПОЛУЧИТЬ КОЛИЧЕСТВО ЭЛЕМЕНТОВ СПИСКА');
        writeln('10 - УДАЛЕНИЕ ВСЕХ ЭЛЕМЕНТОВ ИЗ СПИСКА');
        writeln('11 - ВЫХОД');
        write('Выберите один из предложенных пунктов: ');
        readln(sel);
    until((sel >= 1) and (sel <= 11));
    writeln;
{в качестве ответа функция возвращает номер пункта меню}
    mainMenu := sel;
{конец тела функции}
end;
{---------------------------------------------------------------------------}
{главный блок программы}
{---------------------------------------------------------------------------}
var
{отвечает за пункт меню указанный пользователем}
    sel : integer;
begin
{очистка экрана от прошлых выводов}
    clrscr;
{выделяем память под заглавный элемент списка, который является впоследствии
 неудаляемым элементом}

    new(head);
{ссылается заглавный элемент в NIL}
    head^.link := NIL;
{поскольку список пуст, то присваиваем значение 0}
    head^.inf := '0';
{происходит циклическая визуализация меню для пользователя, до тех пор, пока
 пользователь не выберет пункт, отвечающий за выход из программы}

    repeat
        sel := mainMenu;
        case sel of
            1:
            begin
{добавление элемента в начало списка}
                addElemToBegin;
                writeln('Элемент успешно добавлен в начало списка!');
                readkey;
            end;
            2:
            begin
{добавление элемента в конец списка}
                addElemToEnd;
                writeln('Элемент успешно добавлен в конец списка!');
                readkey;
            end;
            3:
            begin
{добавление элемента перед заданным элементом}
                addElemBeforeTarget;
                readkey;
            end;
            4:
            begin
{добавление элемента после заданного элемента}
                addElemAfterTarget;
                readkey;
            end;
            5:
            begin
{удаление элемента из начала списка}
                delElemFromBegin;
                readkey;
            end;
            6:
            begin
{удаление элемента из конца списка}
                delElemFromEnd;
                readkey;
            end;
            7:
            begin
{удаление срединного элемента из списка}
                delCenterElem;
                readkey;
            end;
            8:
            begin
{печать элементов списка из начала в конец}
                printListFromBeginToEnd;
                readkey;
            end;
            9:
            begin
{получение общего количества элементов списка}
                write('Количество элементов списка: ', getCountElem);
                readkey;
            end;
            10:
            begin
{удаление всех элементов из списка}
                delAllElem;
                writeln('Все элементы успешно удалены из списка!');
                readkey;
            end;
        end;
    until(sel = 11);
{перед тем как закрыть программу, необходимо позаботиться о том, чтобы
 не было утечки памяти, поэтому, следует удалить все элементы из списка}

    delAllElem;
{завершающий оператор программы}
end.

 
 
 
 
Авторизация на сайте
 
 
 
Обнаружили
ошибку на сайте?
Занятия по информатике